Home > Articles

  • Print
  • + Share This
This chapter is from the book

Navigation Between Pages

A typical Web application is a collection of Web pages linked with each other. In Chapter 2, I discussed the HyperLink control that allows a user to navigate to a different Web page when the hyperlink is clicked. However, there is frequently a need to navigate to a Web page programmatically. ASP.NET provides the following methods for programmatically navigating between pages.

  • Response.Redirect()

  • Server.Transfer()

  • Server.Execute()

I'll discuss each of these techniques in turn.

The Response.Redirect() Method

The Response.Redirect() method causes the browser to connect to the specified URL. When the Response.Redirectc) method is called, it creates a response whose header contains a 302 (Object Moved) status code and the target URL. When the browser receives this response from the server, it uses the header information to generate another request to the new URL. When using the Response.Redirect() method, the redirection happens at the client side and involves two round trips to the server.

You should use the Response.Redirect() method in the following cases:

  • You want to connect to a resource on any Web server.

  • You want to connect to a non ASPX resource (such as an HTML file).

  • You want to pass the query string as part of the URL.

The Server.Transfer() Method

The Server.Transfer() method transfers the execution from the current ASPX file to the specified ASPX file. The path specified to the ASPX file must be on the same Web server.

When the Server.Transfer() method is called from an executing ASPX page the current ASPX page terminates execution and the control is transferred to another ASPX page. The new ASPX page still uses the response stream created by the prior ASPX page. When this transfer occurs, the URL in the browser still shows the original page because the redirection occurs on the server side and the browser remains unaware of this transfer.

When you want to transfer the control to an ASPX page residing on the same Web server, you should use Server.Transfer() instead of Response.Redirect() because Server.Transfer() will avoid the unnecessary round trip and provide better performance and a better user experience.

The default use of the Server.Transfer() method does not pass the form data and the query string of the original page request to the transferred page. But, you can preserve the form data and query string of the original page by passing a True value to the optional second argument, preserveForm, of the Server.Transfer() method. The second argument takes a Boolean value that indicates whether to preserve form and query string collection.

When you set the second argument to True, you need to be aware of one thing: The destination page uses the same response stream that was created by the original page, and therefore the hidden _VIEWSTATE field of the original page is also preserved in the form collection. The ViewState is page-scoped and is valid for a particular page only. This causes the ASP.NET machine authentication check (MAC) to announce that the ViewState of the new page has been tampered with. Therefore, when you choose to preserve the form and query string collection of the original page, you must set the EnableViewStateMac attribute of the Page directive to false for the destination page.

The Server.Execute() Method

The Server.Execute() method allows the current ASPX page to execute a specified ASPX page. The path to the specified ASPX file must be on the same Web server.

After the specified ASPX page is executed, the control transfers back to the original page from which the Server.Execute() method was called. This technique of page navigation is analogous to making a function call to an ASPX page.

The called ASPX page has access to the form and query string collections of the calling page and thus for the reasons explained in the previous section, you need to set the EnableViewStateMac attribute of the Page directive to false on the executed page.

By default, the output of the executed page is added to the current response stream. This method also has an overloaded version in which the output of the redirected page can be fetched in a TextWriter object instead of adding the output to the response stream. This helps you to control where to place the output in the original page.

NOTE

Bad HTML Code The output returned to the browser by the Server.Execute() and Server.Transfer() may contain multiple <html> and <body> tags as the response stream remains the same while executing another ASPX pages. Therefore, the resulting output by calling these methods may contain bad HTML code.

STEP BY STEP 3.13 - Using the Response.Redirect(), Server.Transfer(), and Server.Execute() Methods

  1. Add a new Web Form named StepByStep3-13.aspx to your project. Add three Label controls, a Literal control (litDynamic), two TextBox controls (txtRows, txtCells) and three button controls (btnTransfer, btnExecute, and btnRedirect) to the new Web Form as shown in Figure 3.12.

Figure 3.12Figure 3.12 Design of a form that allows you to specify rows and columns to create a table dynamically.

  1. Add a line of code at the top of the Web Form's module:

    Imports System.IO

  2. Add code to handle the events of the Button controls:

    Private Sub btnRedirect_Click( _
     ByVal sender As System.Object, _
     ByVal e As System.EventArgs) _
     Handles btnRedirect.Click
      ' Calling Response.Redirect by passing
      ' Rows and Cells values as query strings
      Response.Redirect("StepByStep3-13a.aspx?Rows=" & _
       txtRows.Text + "&Cells=" + txtCells.Text)
    End Sub
    
    Private Sub btnTransfer_Click( _
     ByVal sender As System.Object, _
     ByVal e As System.EventArgs) _
     Handles btnTransfer.Click
      ' Writing into Response stream
      Response.Write( _
       "The following table is generated " & _
       "by the StepByStep3-13a.aspx page:")
      ' Calling the Server.Transfer method
      ' with the second argument set to true
      ' to preserve the form and query string data
      Server.Transfer("StepByStep3-13a.aspx", True)
      ' Control does not come back here
    End Sub
    
    Private Sub btnExecute_Click( _
     ByVal sender As System.Object, _
     ByVal e As System.EventArgs) Handles btnExecute.Click
      ' Creating a StringWriter object
      Dim sw As StringWriter = New StringWriter()
      ' Calling the Server.Execute method by
      ' passing a StringWriter object
      Server.Execute("StepByStep3-13a.aspx", sw)
      ' Control comes back
      ' Displaying the output in the StringWriter
      ' object in a Literal control
      litDynamic.Text = sw.ToString()

    End Sub

  3. Add a new Web Form to the project. Name the Web Form StepByStep3-13a.aspx. Change the pageLayout property of the DOCUMENT element to FlowLayout.

  4. Add a Table control (tblDynamic) from the Web Forms tab of the Toolbox on the Web Form.

  5. Switch to the HTML view of StepByStep3_11a.aspx file and modify the @Page directive to add the EnableViewStateMac="false" attribute:

    <%@ Page Language="vb" AutoEventWireup="false"
     Codebehind="StepByStep3-13a.aspx.vb"
     Inherits="_305C03.StepByStep3_13a"

    EnableViewStateMac="false"%>

  6. Switch to code view and add the following method to the class definition:

    Private Sub CreateTable(ByVal intRows As Int32, _
     ByVal intCells As Int32)
      ' Create a new table
      Dim trRow As TableRow
      Dim tcCell As TableCell
    
      ' Iterate for the specified number of rows
      Dim intRow As Integer
      Dim intCell As Integer
      For intRow = 1 To intRows
        ' Create a row
        trRow = New TableRow()
        If intRow Mod 2 = 0 Then
          trRow.BackColor = Color.LightBlue
        End If
        ' Iterate for the specified number of columns
        For intCell = 1 To intCells
          ' Create a cell in the current row
          tcCell = New TableCell()
          tcCell.Text = "Cell (" & _
           CStr(intRow) & "," & _
           CStr(intCell) & ")"
          trRow.Cells.Add(tcCell)
        Next
        ' Add the row to the table
        tblDynamic.Rows.Add(trRow)
      Next
    End Sub
  7. Add the following code in the Page_Load() event handler:

    Private Sub Page_Load(ByVal sender As System.Object, _
     ByVal e As System.EventArgs) Handles MyBase.Load
      If Not Request.Form("txtRows") Is Nothing Then
        ' If the request contains form data then the
        ' page is called from the Server.Transfer or
        ' Server.Execute method from the
        ' StepByStep3_13.aspx page. Get the Rows and
        ' Cells value from the form collection and
        ' Create a table.
        CreateTable(Int32.Parse( _
         Request.Form("txtRows")), _
          Int32.Parse(Request.Form("txtCells")))
      ElseIf Not Request.QueryString("Rows") _
       Is Nothing Then
        ' If the request contains query string data
        ' that means the response is redirected from
        ' StepByStep3_14.aspx page. Get the Rows and
        ' Cells values from the query string and
        ' Create a table.
        Response.Write("StepByStep3_13a.aspx:")
        CreateTable( _
         Int32.Parse(Request.QueryString("Rows")), _
         Int32.Parse(Request.QueryString("Cells")))
      End If
    End Sub
  8. Set StepByStep3_13.aspx as the start page for the project.

  9. Run the project. Enter the number of rows and cells and click all three buttons one by one. When you click the Redirect button, the browser is redirected to StepByStep3-13a.aspx and passes the rows and cells values as the query string data, as shown in Figure 3.13. When you click the Transfer button, the browser doesn't change the page name in the location bar but the control gets transferred to the StepByStep3-13a.aspx page as shown in Figure 3.14. Finally, when you click the Execute button, the StepByStep3-13a.aspx page is executed and control comes back to the calling page where the output of Server.Execute() method is displayed as shown in Figure 3.15.

Figure 3.13Figure 3.13 The Response.Redirect() method can be use to navigate to a URL that contains query strings.

Figure 3.14Figure 3.14 The Server.Transfer() method is used to navigate to an ASPX page on the same server without causing an additional round trip.

Figure 3.15Figure 3.15 The Server.Execute() method executes the specified ASPX page and returns the control back to the calling page.

Review Break

  • The Response.Redirect() method can be used to connect to any specified URL. The specified URL can point to any resource and may also contain query strings. The use of Response.Redirect causes an additional round trip to the server.

  • The Server.Transfer() method performs a server-side redirection of a page. The use of Server.Transfer() avoids an extra round trip but only works with an ASPX file residing in the same Web application on the same Web server. Also, when you use the Server.Transfer method, any query string on the original request is not automatically passed to the new page.

  • The Server.Execute method is like a function call to an ASPX file. This method executes the specified ASPX file and then returns execution to the calling ASPX page. The file specified as an argument to the Server.Execute() must be an ASPX file residing on the same Web server and the argument should not contain query string data.

  • + Share This
  • 🔖 Save To Your Account